Menambah kan karakter % di dalam fungsi format

[mas_kofa]

kita tahu, atau bahkan sering menggunakan (bagi yg sering ) fungsi format di delphi....

fungsi format ini menggunakan tanda % untuk menandakan parameter nya....

contoh :

Code:

sss := format('select * from tbsiswa where siswa_name like "%s"', [edNama.Text]);

Maka jika edNama.Text adalah veronica, maka sss adalah select * from tbsiswa where siswa_name like "veronica",

nah sekarang gmn agar hasil dari sss adalah select * from tbsiswa where siswa_name like "%veronica%",

caranya adalah sebagai berikut :

Code:

sss := format('select * from tbsiswa where siswa_name like "%s%s%s"', ['%', edNama.Text, '%']);

semoga bermanfaat....

[Forego]

mantappp,
yg lain lagi dong bos, gi mana klu yg buat angka yg ada koma nya seperti 12,500.05

makasih

[mas_kofa]

pake %.2n kang.....

contoh :

Code:

edJumlah.Text := format('%.2n', [iTotal]);

[Forego]

makasih,
mudah juga ternyata ya

[mas_kofa]

emang biasa nya pake paan??!!

[Forego]

langsung make string gabungan

[A Rahman]

(Thu, 15 Sep 2011 12:44 PM)mas_kofa Wrote:  pake %.2n kang.....

contoh :

Code:

edJumlah.Text := format('%.2n', [iTotal]);

Mas Kofa, kalau begini gimana caranya :

di Edit Text yang dipakai untuk input data keuangan (angka, misalnya jumlah pinjaman).

Pas nginput (edit text diisi) tanda koma pemisah ribuannya dihilangkan.
Trus waktu selsai nginput kembali angkanya di format dg pemisah ribuan spy gampang dibaca.

Di taruhnya di event apa, on key press, on key up, on key down, on exit atau yg mana? bisa kasih contohnya?

Makasih

[mas_kofa]

u/ keperluan itu aku punya dua function, yakni :

Code:

function  DecToStr(ADec: String): String;  //desimal to string;
function  StrToDec(AStr: String; ADec: Integer): String;

cara pakenya.....

1. di OnEnter kita pasang DecToStr
2. di OnExit kita pasang StrToDec
3. di OnkeyPress kita kasih validasi biar angka aja yg boleh masuk....

berikut kode lengkap nya :

Code:

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TForm1 = class(TForm)
    Edit1: TEdit;
    Edit2: TEdit;
    procedure Edit1Enter(Sender: TObject);
    procedure Edit1Exit(Sender: TObject);
    procedure Edit1KeyPress(Sender: TObject; var Key: Char);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

function  DecToStr(ADec: String): String;
var
  i: Integer;
begin
  result := '';
  for i := 1 to Length(ADec) do
  if ADec[i] <> ThousandSeparator then
  result := result + ADec[i];
end;

function  FloatToDec(AReal: Real; ADec: Integer): string;
begin
  result := format('%.*n', [ADec, AReal]);
end;

function  StrToDec(AStr: String; ADec: Integer): String;
var
  r: Real;
begin
  r := StrToFloatDef(AStr, 0);
  result := FloatToDec(r, ADec);
end;



procedure TForm1.Edit1Enter(Sender: TObject);
var
  edt: TEdit;
begin
  edt      := TEdit(Sender);
  edt.Text := DecToStr(edt.Text);
end;

procedure TForm1.Edit1Exit(Sender: TObject);
var
  edt: TEdit;
begin
  edt      := TEdit(Sender);
  edt.Text := StrToDec(edt.Text, 2);
end;

procedure TForm1.Edit1KeyPress(Sender: TObject; var Key: Char);
begin
  if not (Key in ['0'..'9', #8]) then
  Key := #0;
end;

end.

jika edit nya lebih dari satu....tinggal di-asosiasi-kan aja OnEnter, OnExit, dan OnKeyPress nya ke Edit1, biar gak ngetik berulang2....

S'Moga bermanfaat...........